【博客文章2025】Oracle Database 23ai：AI Vector Search笔记与实验8---在Oracle Database 23.5实现本地Ollama中文RAG支持

create or replace procedure proc_ollama_rag_zh(p_question varchar2, p_question_key varchar2 default null)
  is
    v_question_key varchar2(4000);
    v_ollama_in clob;
    v_rag_hint clob;
    v_apex_out clob;
    v_json apex_json.t_values;
    v_result clob;
 begin
    if p_question_key is null then
     v_question_key := p_question;
    else
     v_question_key :=p_question_key;     
    end if;
    apex_web_service.g_request_headers(1).name :=  'Content-Type';
    apex_web_service.g_request_headers(1).value := 'application/json';
    --Search by using vector embedding
    for rec in (select chunk_data from hr.t1chunksollama order by vector_distance(chunk_embedding , func_text_input_ollama(v_question_key), cosine)
    fetch first 25 rows  only)   
    loop
      v_rag_hint := v_rag_hint || rec.chunk_data || chr(10);   
    end loop;  
    v_rag_hint := replace(replace(replace(v_rag_hint, '''', ''), '"', '\"'), chr(10), '\n');
    --
    v_ollama_in := '{
        "model": "qwen2:7b-instruct",
        "messages": [
             {"role": "system", "content": "' || v_rag_hint || '"},
             {"role": "user", "content": "' || p_question || '"}
        ]
    }';  
    v_apex_out := apex_web_service.make_rest_request(
        p_url => 'http://172.25.250.1:11434/v1/chat/completions',
        p_http_method => 'POST',
        p_body => v_ollama_in,
        p_transfer_timeout => 300000
    );
    apex_json.parse(v_json, v_apex_out);
    v_result:= apex_json.get_varchar2(p_path => 'choices[%d].message.content', p0 => 1, p_values => v_json);  
    dbms_output.put_line('*** Result: ' || chr(10) || v_result);
 end;